Bibliothèque eeBud Server Manager

				
					//On inclut les bibliothèques
#include <eeBudServerManager.h>
#include <OneWire.h>
#include <DallasTemperature.h>

//Définition des broches
#define PIN_DS18B20 33  //La broche 33 sera pour la sonde de température DS18B20
#define PIN_LED_BLEUE 14
#define PIN_LED_JAUNE 2
#define PIN_BOUTON 35

//Création du serveur
eeBudServerManager Serveur("KTWF-0005");

//Ces integers seront les identifiants des commandes qui seront disponibles sur l'index (la page d'accueil)
int Serveur_INFO_TEMPERATURE;
int Serveur_LED_BLEUE_OFF;
int Serveur_LED_JAUNE_OFF;
int Serveur_LED_BLEUE_ON;
int Serveur_LED_JAUNE_ON;

//Cet integer sera la variable qui écoutera les évènements retours du serveur. (J'appuie sur un bouton de l'index => évènement)
int Serveur_Event;

//Température
OneWire oneWire(PIN_DS18B20);
DallasTemperature DS18B20(&oneWire);
unsigned long Moment_Present = 0;
unsigned long Moment_Memorise = 0;

//Etat des leds
bool Etat_LED_BLEUE = false;
bool Etat_LED_JAUNE = false;

//Ne sera exécuté qu'une fois au démarrage du module
void setup() {
  //Initialisation du serveur (Création/connexion réseau Wi-Fi)
  Serveur.Init();

  //Mise en page de l'index
  //Sur cet index apparaîtra une information qui donnera la température mesurée
  Serveur_INFO_TEMPERATURE = Serveur.IndexAddInfo("Température", "°C");

  //Apparaîtront également 2 boutons pour allumer ou éteindre les leds intégrées au module
  int *Bouton = Serveur.IndexAddToogle("Led bleue");
  Serveur_LED_BLEUE_OFF = Bouton[0];
  Serveur_LED_BLEUE_ON = Bouton[1];

  Bouton = Serveur.IndexAddToogle("Led Jaune");
  Serveur_LED_JAUNE_OFF = Bouton[0];
  Serveur_LED_JAUNE_ON = Bouton[1];
  //Fin de la mise en page de l'index

  //Réglage des broches
  pinMode(PIN_LED_BLEUE, OUTPUT);  //La broche PIN_LED_BLEUE (pin 14, déclarée plus haut) est une sortie (Envoie du jus vers la led.)
  pinMode(PIN_LED_JAUNE, OUTPUT);
  pinMode(PIN_BOUTON, INPUT);

  //J'éteins les leds au démarrage du module
  Fonction_Led_Bleue_Off();
  Fonction_Led_Jaune_Off();
}

//S'éxécutera en boucle tout le temps que le module sera sous tension
void loop() {
  //Ecoute des évènements sur le serveur (intéraction avec l'index ou les requêtes HTTP)
  Serveur_Event = Serveur.IndexGetEvent();

  if (Serveur_Event == Serveur_LED_BLEUE_OFF) {  //Si l'évènement a capté un appui sur le bouton Off de la led bleue
    Fonction_Led_Bleue_Off();                    //J'éteins la led bleue
    Serveur.IndexResetEvent();                   //Je réinitialise l'évènement
  } else if (Serveur_Event == Serveur_LED_BLEUE_ON) {
    Fonction_Led_Bleue_On();
    Serveur.IndexResetEvent();
  } else if (Serveur_Event == Serveur_LED_JAUNE_OFF) {
    Fonction_Led_Jaune_Off();
    Serveur.IndexResetEvent();
  } else if (Serveur_Event == Serveur_LED_JAUNE_ON) {
    Fonction_Led_Jaune_On();
    Serveur.IndexResetEvent();
  }

  //Gestion de la température
  //La température sera mesurée toutes les 30000 ms
  Moment_Present = millis();
  if ((Moment_Present - Moment_Memorise) > 30000) {
    Moment_Memorise = Moment_Present;

    //Prise de la température
    DS18B20.requestTemperatures();
    
    //J'écris la température mesurée sur l'index
    Serveur.IndexSetInfo(Serveur_INFO_TEMPERATURE, String(DS18B20.getTempCByIndex(0)));
  }

  //Gestion du bouton
  if (digitalRead(PIN_BOUTON) == LOW) {            // Si le bouton intégré à la carte est appuyé
    if (Etat_LED_BLEUE) Fonction_Led_Bleue_Off();  //Si la led bleue est allumée, je l'éteins
    else Fonction_Led_Bleue_On();                  //Sinon je l'allume

    if (Etat_LED_JAUNE) Fonction_Led_Jaune_Off();
    else Fonction_Led_Jaune_On();

    //Je bloque le module pendant une demi seconde pour ne pas que l'action ne se répète plusieurs fois lorsque j'appuie sur le bouton
    delay(500);
  }
}

//Fonction qui éteins la led bleue
void Fonction_Led_Bleue_Off() {
  Serveur.IndexSetToogle(Serveur_LED_BLEUE_OFF);  //Je bascule le bouton de l'index sur OFF
  digitalWrite(PIN_LED_BLEUE, LOW);               //J'éteins la led
  Etat_LED_BLEUE = false;                         //Je passe l'état de la led à OFFF
}

void Fonction_Led_Bleue_On() {
  Serveur.IndexSetToogle(Serveur_LED_BLEUE_ON);
  digitalWrite(PIN_LED_BLEUE, HIGH);
  Etat_LED_BLEUE = true;
}

void Fonction_Led_Jaune_Off() {
  Serveur.IndexSetToogle(Serveur_LED_JAUNE_OFF);
  digitalWrite(PIN_LED_JAUNE, LOW);
  Etat_LED_JAUNE = false;
}

void Fonction_Led_Jaune_On() {
  Serveur.IndexSetToogle(Serveur_LED_JAUNE_ON);
  digitalWrite(PIN_LED_JAUNE, HIGH);
  Etat_LED_JAUNE = true;
}