eeBud server manager

				
					// On inclut les bibliothèques
#include <eeBudServerManager.h>
#include <OneWire.h>
#include <DallasTemperature.h>

//Définition des pins
#define DS18B20_PIN 33
#define LED 32
#define BOUTON_TACTILE 14


//Création du serveur qui sera nommé "LED connectée".
eeBudServerManager Serveur("LED connectée");

//ID pour la création de l'index eeBud Server Manager et la récupération des paramètres.
int Info_Temperature;
int *Bouton;

//Variable qui écoutera les remontées du serveur
int Event;

//Température
OneWire oneWire(DS18B20_PIN);
DallasTemperature DS18B20(&oneWire);
float Memoire_Temperature = 9999;
unsigned long Moment_Present = 0;
unsigned long Moment_Memorise = 0;
float Temperature_Actuelle;
float Difference_Temperature_Parametree;

//Tactile
bool Etat_LED;
int Sensibilite_Tactile;
int Valeur_Tactile;

void setup() {
  //Initialisation du serveur.
  Serveur.Init();

  //Création de paramètres stockés en mémoire flash
  Serveur.AddParamText("Différence de température", "0.5");
  Serveur.AddParamText("Sensibilité du tactile", "20");
  Serveur.AddParamText("URL Température", "");
  Serveur.AddParamText("URL Etat", "");
  
  //Récupération de ces paramètres en Variable
  Sensibilite_Tactile = (Serveur.GetParamText("Sensibilité du tactile")).toInt();
  Difference_Temperature_Parametree = Serveur.GetParamText("Différence de température").toFloat();

  //Mise en page de l'index
  Info_Temperature = Serveur.IndexAddInfo("Température", "°C", "60");  // Nom, Unité, Taille de la police.
  Serveur.IndexAddSeg();
  Bouton = Serveur.IndexAddToogle("Etat de la LED", "Off", "On", "Off");
  Serveur.IndexAddSeg();

  //LED
  pinMode(LED, OUTPUT);
  Led_Off();
}

void loop() {

  //Gestion de la température
  Moment_Present = millis();
  if ((Moment_Present - Moment_Memorise) > 30000) {
    Moment_Memorise = Moment_Present;
    DS18B20.requestTemperatures();
    Temperature_Actuelle = DS18B20.getTempCByIndex(0);

    if ((Memoire_Temperature - Temperature_Actuelle) >= Difference_Temperature_Parametree || (Temperature_Actuelle - Memoire_Temperature) >= Difference_Temperature_Parametree) {
      Memoire_Temperature = Temperature_Actuelle;
      //Ecriture de la température sur l'index
      Serveur.IndexSetInfo(Info_Temperature, String(Temperature_Actuelle));
      String URL_Temperature = Serveur.GetParamText("URL Température");
      URL_Temperature.replace("#VALUE#", String(Temperature_Actuelle));
      //Envoi de l'information au serveur domotique (Jeedom)
      Serveur.HTTPPost(URL_Temperature);
    }
  }

  //Gestion de la LED depuis l'index
  //Si l'écouteur a recu l'information d'appui sur le bouton de l'index
  Event = Serveur.IndexGetEvent();
  if (Event == Bouton[0]) {
    Led_Off();
  } else if (Event == Bouton[1]) {
    Led_On();
  }

  //Gestion de la LED depuis le tactile
  Valeur_Tactile = touchRead(BOUTON_TACTILE);
  if (Valeur_Tactile < Sensibilite_Tactile) {
    if (Etat_LED == false) {
      Led_On();
    } else {
      Led_Off();
    }
    delay(500);
  }
}

void Led_Off() {
  digitalWrite(LED, LOW);
  //Bascule du bouton sur l'index
  Serveur.IndexSetToogle(Bouton[0]);
  String URL_Etat = Serveur.GetParamText("URL Etat");
  URL_Etat.replace("#VALUE#", "0");
  //Envoi de l'information au serveur domotique (Jeedom)
  Serveur.HTTPPost(URL_Etat);
  Serveur.IndexResetEvent();
  Etat_LED = false;
}

void Led_On() {
  digitalWrite(LED, HIGH);
  //Bascule du bouton sur l'index
  Serveur.IndexSetToogle(Bouton[1]);
  String URL_Etat = Serveur.GetParamText("URL Etat");
  URL_Etat.replace("#VALUE#", "1");
  //Envoi de l'information au serveur domotique (Jeedom)
  Serveur.HTTPPost(URL_Etat);
  Serveur.IndexResetEvent();
  Etat_LED = true;
}